Create an Instagram mosaic

source ./create_ig_mosaic.sh && create_ig_mosaic

create_ig_mosaic "dogs_original.jpg"

chmod +x create_ig_mosaic.sh \
 && source ./create_ig_mosaic.sh \
 && create_ig_mosaic  "$HOME/Downloads/pexels-blue-bird-7210754.jpg"

#!/usr/bin/env zsh

# vim: set ts=2 sts=2 sw=2 expandtab tw=0 :

create_ig_mosaic() {
  # Example usage:
  # Basic usage with default values (processes img_original.jpg)
  # create_ig_mosaic
  #
  # Typical Instagram mosaic creation:
  # - Input: your_photo.jpg
  # - Output: 3 tiles (1010x1350 each with 35px padding)
  # - Quality: 85%
  # - Float preccision: 4
  # - Output directory: ./mosaic_output
  # create_ig_mosaic "your_photo.jpg" 3030 1350 35 3 85 4 "./mosaic_output"
  
  # Get image
  local image_original=${1:-img_original.jpg}

  # Check if file exists
  if [ ! -f "$image_original" ]; then
    echo "File not found: $image_original"
    return 1
  fi

  # Get final width and height
  local image_final_w=${2:-3030} # 1010 * 3
  local image_final_h=${3:-1350}
  local image_final_w_padd=${4:-35}

  # Number of images (same height)
  local n_imgs=${5:-3}

  # Quality percentage to maintain
  local quality=${6:-85}

  # Float preccision
  local scale=${7:-3}

  # Output directory
  local output_dir=${8:-$(dirname "$image_original")}
  
  # Get width and height
  get_image_dimensions "$image_original" | { read image_w image_h; }
  echo "Image width:  $image_w"
  echo "Image height: $image_h"

  # Calculate ratios
  local aspect_ratio=$(echo "scale="$scale"; $image_w / $image_h" | bc)
  echo "Aspect ratio: $aspect_ratio"
  local aspect_ratio_desired=$(echo "scale="$scale"; $image_final_w / $image_final_h" | bc)
  echo "Aimed ratio: $aspect_ratio_desired" # 2.24
  local h_ratio=$(echo "scale="$scale"; $image_h / $image_final_h" | bc)
  local w_ratio=$(echo "scale="$scale"; $image_w / $image_final_w" | bc)
  echo "Height ratio: $h_ratio"
  echo "Width  ratio: $w_ratio"

  # If the aspect ratio is smaller than the desired aspect ratio then add horizontal white borders, otherwise add them vertically
  local image_padded="$output_dir"/$(add_suffix_before_ext "$image_original" "_padded")
  local dimensions="${image_w}x${image_h}"
  if [ $(echo "$aspect_ratio < $aspect_ratio_desired" | bc) -eq 1 ]; then
    image_w_new=$(echo "scale="$scale"; $image_final_w * $h_ratio" | bc)
    dimensions="${image_w_new}x${image_h}"
  else
    image_h_new=$(echo "scale="$scale"; $image_final_h * $w_ratio" | bc)
    dimensions="${image_w}x${image_h_new}"
  fi
  convert "$image_original" -background white -gravity center -extent "$dimensions" "$image_padded"
  
  # Resize
  local image_resized="$output_dir"/$(add_suffix_before_ext "$image_padded" "_resized")
  dimensions="${image_final_w}x${image_final_h}"
  convert "$image_padded" -resize $dimensions -quality $quality "$image_resized"

  # Check width and height
  get_image_dimensions "$image_original" | { read image_w_resized image_h_resized; }
  echo "Image width:  $image_w_resized"
  echo "Image height: $image_h_resized"

  # Divide in $n_imgs of equal height
  local dimension_w=$(echo "scale=0; $image_final_w / $n_imgs" | bc)
  dimensions="${dimension_w}x${image_final_h}"
  convert "$image_resized" -crop "$dimensions" +repage "$output_dir"/tile_%d.jpg

  # Extend each section to 1080x1350 pixels by adding 35 pixels of extra space to both the left and right sides
  (( dimension_w += 2 * image_final_w_padd ))
  dimensions="${dimension_w}x${image_final_h}"
  for file in "$output_dir"/tile_*.jpg; do
    convert "$file" -background white -gravity center -extent "$dimensions" "$file"
    echo -n "$file dims: "
    echo $(get_image_dimensions "$file")
  done

  # Open imgs side-by-side
  local imgs_to_preview=("$output_dir"/tile_*.jpg)
  open_imgs_side_by_side $imgs_to_preview
}

open_imgs_side_by_side() {
  # Accept an array of files as input
  local files=("$@")
  local n_imgs=${#files}  # Use all files by default

  # Optional: Limit to first N images (uncomment if needed)
  # local max_imgs=3
  # (( n_imgs > max_imgs )) && n_imgs=$max_imgs
  # files=("${files[@]:1:$n_imgs}")  # zsh uses 1-based indexing

  # Get screen width
  local SCREEN_WIDTH=$(xwininfo -root | awk '/Width:/ {print $2}')
  local WIDTH=$((SCREEN_WIDTH / n_imgs))
  (( WIDTH *= 1.01 ))  # Small overlap adjustment

  # Array to store PIDs
  local pids=()

  # Process images
  for (( i=1; i<=n_imgs; i++ )); do
    eog "${files[i]}" &
    pids+=($!)

    sleep 0.5  # Wait for window to open

    local X_POS=$(( (i-1) * WIDTH ))  # X position starts at 0
    xdotool search --name "${files[i]##*/}" windowactivate --sync \
      windowsize %@ "$WIDTH" 100% windowmove %@ "$X_POS" 0
  done

  wait $pids[@]
}

get_image_dimensions() {
  local image_file=$1
  local exif_output=$(exiftool "$image_file")
  local width=$(echo "$exif_output" | grep "Image Width" | awk -F': ' '{print $2}')
  local height=$(echo "$exif_output" | grep "Image Height" | awk -F': ' '{print $2}')
  if [ -z "$width" ] || [ -z "$height" ]; then
    return 1
  fi
  echo "$width $height"
}

add_suffix_before_ext() {
  local filename=$1      # full filename, e.g. img_original.jpg
  local suffix=$2        # suffix to add, e.g. _padded

  # Extract basename without extension and extension using zsh modifiers
  local base=${filename:t:r}   # filename without path and extension
  local ext=${filename:e}      # extension without dot

  # Compose new filename with suffix before extension
  if [[ -n $ext ]]; then
    echo "${base}${suffix}.${ext}"
  else
    # If no extension, just add suffix at end
    echo "${base}${suffix}"
  fi
}